Получить список переданных аргументов в пакетном скрипте Windows (.bat)

Я хотел бы найти пакетный аналог Windows для Bash, $@который содержит список всех аргументов, переданных в скрипт.

Или я должен беспокоиться shift?

10.12.2008 19:38:38
14 ОТВЕТОВ
РЕШЕНИЕ

У dancavallaro это правильно, %*для всех параметров командной строки (за исключением самого имени скрипта). Вы также можете найти их полезными:

%0- команда используется для вызова пакетного файла (может быть foo, ..\foo, c:\bats\foo.batи т.д.)
%1является первым параметром командной строки,
%2является вторым параметром командной строки,
и так далее , пока %9SHIFTможет быть использован для тех , кто после 9 - го).

%~nx0- фактическое имя пакетного файла, независимо от вызывающего метода (some-batch.bat)
%~dp0- диск и путь к скрипту (d: \ scripts)
%~dpnx0- это полное имя пути скрипта (d: \ scripts \ some -batch.bat)

Дополнительные примеры информации на https://www.ss64.com/nt/syntax-args.html и https://www.robvanderwoude.com/parameters.html

614
27.12.2018 21:58:40
Обратите внимание, что SHIFT не влияет на% *, что делает невозможным использование SHIFT [/ n] для некоторого интуитивно-понятного доступа к командной строке, начиная с n-го параметра.
Van Jone 14.03.2013 11:45:21
Что-то еще, что я обнаружил, это то, %~dpn0что вернет диск и путь к скрипту плюс имя пакетного файла, но не расширение. Я нашел это особенно полезным при создании пакетных сценариев, которые вызывают .ps1файл с тем же именем. По сути, dотносится к диску, pотносится к пути, nотносится к имени файла и xотносится к расширению. С этой информацией вы можете сделать довольно много.
Dan Atkinson 3.03.2017 09:05:41
Из любопытства предположим, что я хочу использовать ECHO для распечатки пути к файлу, но заменив его расширение, как это будет происходить?
Matheus Rocha 16.11.2018 21:30:06
@MatheusRocha@echo %~n0.my_ext
matt wilkie 17.11.2018 22:02:43
@mattwilkie Спасибо, я понял это с помощью ECHO, чтобы увидеть, что он напечатает в результате.
Matheus Rocha 17.11.2018 22:13:26

%* кажется, содержит все аргументы, переданные сценарию.

146
10.12.2008 19:44:28
Любая идея, почему он не обрабатывает некоторые символы, такие как &? Когда я пытаюсь получить несколько путей к нескольким выбранным файлам (используя меню «Отправить» и «% *», которые передают аргументы в .py), он останавливает листинг в & caracters. Так, если, например, второй файл содержит &в своем имени a , часть имени после него &будет пропущена, а также оставшиеся файлы.)
JinSnow 2.05.2017 20:36:45
@JinSnow Это &специальный символ, который означает stop this command and start another one. Имя файла, содержащее & ДОЛЖНО быть заключено в кавычки.
Jesse Chisholm 27.10.2018 18:41:04

%1... %nи %*содержит аргументы, но получить к ним доступ может быть сложно, потому что контент будет интерпретирован.
Поэтому с такими заявлениями невозможно справиться

myBatch.bat "&"^&

Каждая строка завершается ошибкой, поскольку cmd.exe пытается выполнить один из амперсандов (содержимое% 1 равно "&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

Но существует обходной путь с временным файлом

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Хитрость заключается в том, чтобы включить echo onи развернуть оператор %1после rem(работает также с% 2 ..% *).
Но чтобы иметь возможность перенаправить вывод echo on, вам нужны два цикла FOR-LOOPS.

Дополнительные символы * #используются для обеспечения безопасности содержимого /?( например , для справки по REM).
Или символ ^ в конце строки может работать как многострочный символ.

FOR / F должен работать с отложенным расширением, иначе содержимое с "!" будет уничтожен.
После удаления лишних символов param1и у вас это получилось.

И для param1безопасного использования включите отложенное расширение.

Изменить: одно замечание к% 0

%0содержит команду, используемую для вызова пакета, также сохраняя регистр, как в FoO.BaT
Но после вызова функции, %0а также в %~0содержит имя функции (или лучше строку, которая использовалась для вызова функции).
Но с %~f0вами еще можно вспомнить имя файла.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

Вывод

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat
64
7.09.2015 07:35:38
+++ 1 OMG - %~f0уловка совершенно неожиданная, крутая и потенциально очень полезная :-) Неудивительно, что другие модификаторы работают одинаково, всегда работая с родительским пакетным файлом, даже в вызываемой подпрограмме. Это кажется достойным его собственных вопросов и ответов - «Как получить доступ к имени запущенного пакета в вызываемой подпрограмме?»
dbenham 30.03.2012 15:13:49
Если я правильно помню, вы можете использовать call с аргументами, и они будут храниться в% 1,% 2, ...% n, как при запуске скрипта.
Nulano 25.11.2014 21:10:03

Я обнаружил, что в следующий раз, когда вам нужно найти эту информацию. Вместо того, чтобы открывать браузер и гуглить, вы можете просто ввести call /?свой cmd, и вы получите его:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*
48
17.05.2012 13:42:45

Способ получить все аргументы скрипта здесь:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause
19
4.06.2013 15:36:45
Не совсем, %%Iполучить интерпретацию и может сломать ваш сценарий.
Boris Brodski 11.01.2017 12:00:34

Вот довольно простой способ получить аргументы и установить их как env vars. В этом примере я буду ссылаться на них как на ключи и значения.

Сохраните следующий пример кода как «args.bat». Затем вызовите пакетный файл, который вы сохранили из командной строки. пример: arg.bat --x 90 --y 120

Я предоставил несколько эхо-команд, чтобы пройти через весь процесс. Но конечный результат заключается в том, что --x будет иметь значение 90, а --y будет иметь значение 120 (то есть, если вы запустите пример, как указано выше ;-)).

Затем вы можете использовать условный оператор if if, чтобы определить, следует ли запускать ваш блок кода. Допустим, запустим: «arg.bat --x hello-world». Тогда я мог бы использовать выражение «IF DEFINED --x echo% - x%», и в результате получился бы «hello-world». Это должно иметь больше смысла, если вы запустите пакет.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done
5
17.04.2018 20:34:02
Это очень полезно!
robe007 5.07.2019 21:50:46
@ эхо выключено
:Начните

:: Вставьте свой код здесь
echo. %% 1 сейчас:% ~ 1
:: Конец введите свой код здесь

если "% ~ 2" NEQ "" (
    сдвиг
    перейти к началу
)
0
12.02.2014 12:49:25

Версия для Windows (хотя требуется socat)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

настройка:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd
-1
26.06.2015 07:55:56

Следующий код имитирует массив (' params') - принимает параметры, полученные сценарием, и сохраняет их в переменных params_1.. params_n, где n= params_0= количество элементов массива:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof
2
21.01.2016 13:41:15

Большая часть информации, приведенной выше, привела меня к дальнейшим исследованиям и, в конечном итоге, к моему ответу, поэтому я хотел поделиться тем, что я делал, в надежде, что это поможет кому-то еще:

  • Я также хотел передать переменное количество переменных в пакетный файл, чтобы они могли быть обработаны в файле.

  • Я был в порядке с передачей их в командный файл, используя кавычки

  • Я хотел бы, чтобы они обрабатывались аналогично приведенному ниже - но с использованием цикла вместо записи вручную:

Поэтому я хотел выполнить это:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

И с помощью цикла for сделайте это внутри командного файла:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

У меня была проблема, что все мои попытки использовать цикл for не работали. Пример ниже:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

просто сделал бы:

set "_appPath=C:\Services\Logs\PCAP"

и не:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

даже после настройки

SETLOCAL EnableDelayedExpansion

Причина была в том, что цикл for прочитал всю строку и назначил мой второй параметр %% B во время первой итерации цикла. Поскольку% * представляет все аргументы, обрабатывается только одна строка - поэтому происходит только один проход цикла for. Это по замыслу оказывается, и моя логика оказалась неверной.

Поэтому я перестал пытаться использовать цикл for и упростил то, что пытался сделать, используя if, shift и оператор goto. Согласен, это немного взломать, но это больше подходит для моих нужд. Я могу перебрать все аргументы, а затем использовать оператор if, чтобы выйти из цикла, как только обработаю их все.

Заявление о победе за то, что я пытался сделать:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

ОБНОВЛЕНИЕ - вместо этого мне пришлось изменить приведенное ниже, я выставлял все переменные окружения, пытаясь сослаться на% 1 и используя shift таким образом:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)
0
30.03.2016 22:04:32
Я не прав, сделал еще несколько проверок и после 3-й итерации моя команда shift выставляет все переменные окружения, что нарушает вышеприведенное. Я все еще изучаю, есть ли способ обойти это.
John Ahearn 30.03.2016 21:47:24
Пришлось внести изменение, вместо того, чтобы использовать% 1, мне пришлось сначала сместиться один раз и использовать% 0, иначе я столкнулся со странной проблемой, когда в итоге% 1 содержал все текущие переменные среды.
John Ahearn 30.03.2016 22:01:58

Если в кавычках есть параметры, содержащие пробелы, %*они не будут работать правильно. Лучшее решение, которое я нашел, - это цикл, объединяющий все аргументы: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)
1
17.08.2018 13:36:21

введите описание изображения здесь

Чтобы использовать цикл для получения всех аргументов и в чистом пакетном режиме:

Obs: Для использования без:?*&<>


@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!")

:: write/test these arguments/parameters ::
for /l %%l in (1 1 !_cnt!)do echo/ The argument n:%%l is: !_arg_[%%l]!

goto :eof 

Ваш код готов сделать что-то с номером аргумента там, где это необходимо, например ...

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"

echo= !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt
3
12.02.2020 13:08:30

Вы можете использовать ForCommad, чтобы получить список Arg.

Помощь: For /? Помощь:Setlocal /?

Вот мой путь =

@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER Scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
 Echo Arg_!Count! = %%I
 set /a Count+=1 
)
Echo Count Of Args = !Count!
Endlocal

Не нужна команда Shift.

1
8.04.2020 13:18:21

Иногда мне нужно извлечь несколько параметров командной строки, но не все и не из первого. Давайте предположим следующий вызов:

Test.bat uno dos tres cuatro cinco seis siete

Конечно, расширение ".bat" не нужно, по крайней мере, у вас есть test.exe в той же папке. Мы хотим получить вывод «tres cuatro cinco» (независимо от того, одна строка или три). Цель состоит в том, что только мне нужны три параметра, начиная с третьего. Чтобы иметь простой пример, действие для каждого из них просто «эхо», но вы можете подумать о некоторых других более сложных действиях над выбранными параметрами.

Я привел несколько примеров (вариантов), чтобы вы могли увидеть, какой из них вы считаете лучшим для вас. К сожалению, нет хорошего (или я не знаю о) способа, основанного на цикле for в диапазоне, таком как "for %% i in (% 3, 1,% 5)".

@echo off 
setlocal EnableDelayedExpansion

echo Option 1: one by one (same line)
echo %3, %4, %5
echo.

echo Option 2: Loop For one by one
for %%a in (%3, %4, %5) do echo %%a
echo.

echo Option 3: Loop For with check of limits
set i=0
for %%a in (%*) do (
    set /A i=i+1
    If !i! GTR 2 if !i! LSS 6 echo %%a
)
echo.

echo Option 4: Loop For with auxiliary list
for /l %%i in (3,1,5) do  (
    set a=%%i
    set b=echo %%
    set b=!b!!a!
    call !b!
)
echo.

echo Option 5: Assigning to an array of elements previously
set e[0]=%0
set i=0 
for %%a in (%*) do (
    set /A i=i+1
    set e[!i!]=%%a
)
for  /l %%i in (3,1,5) do (
    echo !e[%%i]!
)
echo.

echo Option 6: using shift and goto loop. It doesn't work with for loop
set i=2
:loop6
    set /A i=i+1
    echo %3
    shift
    If %i% LSS 5 goto :loop6

Вероятно, вы можете найти больше вариантов или объединить несколько. Наслаждайся ими.

0
5.02.2020 15:26:44