Как я могу передать аргументы в командный файл?

Мне нужно передать идентификатор и пароль в командный файл во время выполнения, а не жестко закодировать их в файл.

Вот как выглядит командная строка:

test.cmd admin P@55w0rd > test-log.txt
25.08.2008 18:14:18
«Все остальное» смотрите в комментарии Грега Хегилла о том, как получить параметры командного файла из N-й позиции?
matt wilkie 7.01.2014 21:04:33
У меня есть сценарий запуска среды, который будет выдвигать мое имя пользователя / пароль в переменные среды ... чтобы мне не приходилось каждый раз печатать их ... Хотя я использую bash большую часть времени (linux, mac и Windows), и нужно использовать его для настройки прокси в скриптах и ​​т. д. для работы.
Tracker1 7.10.2015 04:35:33
17 ОТВЕТОВ

Да, и просто не забудьте использовать переменные, как %%1при использовании ifи forи банды.

Если вы забудете о двойном %, то вы будете подставлять (возможно, нулевые) аргументы командной строки, и вы получите несколько довольно запутанных сообщений об ошибках.

60
25.08.2008 18:16:32
%% только для ifа for?
Royi Namir 27.10.2012 17:01:27
Хуже того - %% используется для префикса переменных и параметров командной строки внутри командных файлов. Но когда вы используете эти команды из командной строки, вы используете только% для префикса. Пример: внутри пакета: for %%d in (*) do echo %%dиз командной строки:for %d in (*) do echo %d
Steve Midgley 16.01.2013 17:08:50
@ SteveMidgley Я проголосовал за ваш комментарий, вероятно, год или около того назад. Затем я быстро забыл об этом, и только сегодня я пытался и смущенно уставился на цикл for в командной строке и удивился, почему он пукнул и больше ничего не сделал. Итак, вот еще одно виртуальное возражение от меня. Я вернусь через год или около того, когда снова затрону ту же проблему.
icc97 29.12.2016 21:53:47
Обычно мы резервируем цифры для обработки командной строки, и, насколько мне известно, двойной процент применяется только к оператору for. @for %%2 in (testing) do @echo %%2 %1в командном файле выдает, testing 1когда он вызывается с помощью 1 ( test 1).
jwdonahue 22.01.2018 03:07:00
Ответ неверный. %%1не имеет доступа к аргументу командной строки, и это также неправильно для IFкоманды. Только FORкоманда (в пакетных файлах) требует двойного процента, но даже тогда она %%1будет определять параметр FOR и не будет иметь доступа к аргументам
jeb 3.03.2020 07:08:52

Еще один полезный совет - использовать %*для обозначения «все». Например:

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

Когда вы бежите:

test-command admin password foo bar

вышеуказанный командный файл будет работать:

fake-command /u admin /p password admin password foo bar

У меня может быть немного неправильный синтаксис, но это общая идея.

1022
23.11.2018 22:08:09
% * фактически распространяется на все параметры независимо от смещения. Таким образом, даже после двух смен вы получите первые два аргумента в% *. Вы можете использовать что-то вроде этого: stackoverflow.com/questions/761615/… чтобы получить переменную, которая содержит все, кроме первых n параметров.
Joey 1.05.2009 20:52:18
Обратите внимание, что% * не работает везде! Например, он не работает с DOSBox 0.73 (возможно, это ошибка, о которой следует сообщать).
Denilson Sá Maia 8.02.2010 02:50:16
Это не ошибка, потому что% * никогда не работал в MS-DOS или Win9x.
Kef Schecter 23.11.2011 04:54:55
Что это за линии "сдвига"?
beppe9000 19.04.2016 10:44:33
Этот ответ неверен. Это на самом деле приводит к fake-command /u admin /p password admin password foo bar. На это указал @Joey много лет назад.
jwdonahue 22.01.2018 03:32:16

Если вы хотите разумно обрабатывать пропущенные параметры, вы можете сделать что-то вроде:

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1
142
25.08.2008 20:03:34
Каково значение точки / периода в этих операциях равенства?
Chris 27.02.2017 15:22:38
В основном, если% 1 пуст, это в конечном итоге будет IF. == и так GOTO произойдет. Мы используем x здесь так: ЕСЛИ x% 1 == x -> IF x == x -> true
Carl 2.03.2017 14:48:23
Не ответ на вопрос.
jwdonahue 22.01.2018 01:12:10
Вы должны спросить, какова ценность «необоснованного аргумента»? Против того, что вы должны проверить «необоснованный аргумент»? Затем, если у вас нет ответа, вы должны использовать трюк, подобный одному из точек. Помните, что, как указано здесь: ss64.com/nt/if.html "На самом деле вы можете использовать практически любой символ для этой '~' или фигурных скобок, {} или даже числа 4, но квадратные скобки, как правило, выбираются потому, что у них нет особого значения ".
Adriano G. V. Esposito 15.03.2018 13:39:27
РЕШЕНИЕ

Вот как я это сделал:

@fake-command /u %1 /p %2

Вот как выглядит команда:

test.cmd admin P@55w0rd > test-log.txt

%1Относится к первому параметру в %2(а вот хитрая часть) относится ко второму. Таким способом можно передать до 9 параметров.

281
10.02.2019 18:22:26
Если вы такой же тупой, как и я, ваш разум искал echo %1 %2и был отброшен простейшим случаем без вырезов и вставки с параметрами a @и a fake-commandс параметрами, думая, что мы получим fake-command.batсодержимое позже (в этом случае слишком сложный, fake-command.batвозможно, придется echo %2 %4игнорировать имена параметров). Неправильно, глупец. TL; DR: не будь таким тупым, как я. 1. echo echo %1 %2 > test.bat2 test word1 word2.. 3. Прибыль.
ruffin 5.03.2015 18:26:52

Создайте новый пакетный файл (пример: openclass.bat) и запишите эту строку в файл:

java %~n1

Затем поместите пакетный файл, скажем, в папку system32, перейдите в файл классов Java, щелкните правой кнопкой мыши «Свойства», «Открыть с помощью ...», затем найдите свой пакетный файл, выберите его и все ...

Меня устраивает.

PS: я не могу найти способ закрыть окно cmd, когда я закрываю класс Java. Теперь...

4
30.10.2015 15:56:28
Вы можете закрыть окно cmd после закрытия процесса, используя следующую команду в пакетном скрипте:start /wait java %~n1
Paint_Ninja 31.07.2016 16:38:02
Консультирование общественности о размещении случайных файлов сценариев в каталоге system32 является безответственным. Этот ответ действительно не царапает поверхность темы этой темы.
jwdonahue 22.01.2018 03:24:36

Доступ к пакетным параметрам может быть простым с% 1,% 2, ...% 9 или также% *,
но только если содержимое простое.

Для такого сложного содержимого не существует простого способа "&"^&, так как невозможно получить доступ к% 1 без появления ошибки.

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

Линии расширяются до

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

И каждая строка терпит неудачу, так как одна из них &находится вне кавычек.

Это можно решить с помощью чтения из временного файла отмеченной версии параметра.

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Хитрость заключается в том, чтобы включить echo onи развернуть% 1 после remоператора (работает также с %2 .. %*).
Так что даже "&"&можно повторить, не вызывая ошибки, как это отмечено.

Но чтобы иметь возможность перенаправить вывод echo on, вам нужны два цикла for.

Дополнительные символы * #используются для обеспечения безопасности содержимого /?( например , для справки REM).
Или символ ^ в конце строки может работать как многострочный символ, даже после a rem.

Затем внимательно читаем вывод параметра rem из файла, но внимательно.
FOR / F должен работать с отложенным расширением, иначе содержимое с "!" будет уничтожен.
После удаления лишних символов param1, вы получили его.

И для param1безопасного использования включите отложенное расширение.

88
9.08.2018 14:02:58
for / F "tokens = *" %% a in ('echo% *') действительно установить "all_args = %% a"
Kevin Edwards 11.04.2017 19:39:48
@KevinEdwards Тогда попробуйте с одним &, ваше решение работает только с простым содержимым
jeb 11.04.2017 20:05:06
@KevinEdwards Я проверил это, test.bat ^&и это не удалось . Только test.bat "&"работает, но это не моя точка зрения. Вы не можете использовать %*, %1безопасным способом без РЗМ техники
jeb 13.04.2017 17:47:05
Ах, да, карета не избежит этого должным образом. Вам нужны цитаты, которые выполнимы для всех случаев использования, с которыми я сталкивался. Я просто хотел передать это. Спасибо за тестирование! Приветствия :)
Kevin Edwards 15.04.2017 03:27:51
У меня есть опасения по поводу этого метода (трюк echo-on-and-rem-piped-to-a-file): хотя batch и cmd.exe не разрешают переводы строк в аргументах команд, но для оболочек, которые позволяют это при вызове сценарий, трюк ломается . И не смейтесь, потому что PowerShell допускает переносы в аргументах. Использование низкоуровневой функции CreateProcess () также позволяет создать новую строку и разбить ее.
Explorer09 25.04.2017 14:16:47

Нет необходимости усложнять это. Это просто команда% 1% 2 параметров, например,

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

«Пауза» отображает действия пакетного файла и ждет, когда вы нажмете ЛЮБУЮ клавишу. Сохраните это как xx.bat в папке Windows.

Чтобы использовать его, наберите, например:

xx c:\f\30\*.* f:\sites\30

Этот пакетный файл заботится обо всех необходимых параметрах, таких как копирование только тех файлов, которые новее, и т. Д. Я использовал его еще до Windows. Если вам нравится видеть имена файлов во время их копирования, не указывайте Qпараметр.

51
16.05.2017 10:56:05

Для ссылки на переменную set в командной строке вам необходимо использовать, %a%например:

set a=100 
echo %a%  
rem output = 100 

Примечание: это работает для Windows 7 Pro.

9
16.02.2019 13:02:23
@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

Примечание: ЕСЛИ "%1"==""вызовет проблемы, если %1заключено в кавычки.

В этом случае используйте вместо , IF [%1]==[]или только в NT 4 (SP6) и более поздних версиях IF "%~1"=="".

32
15.11.2016 12:49:39
Правда, но это едва затрагивает предмет.
jwdonahue 22.01.2018 03:12:27
FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

Это циклически повторяет пакетные параметры (% *), либо они заключены в кавычки, либо нет, а затем отображает каждый параметр.

20
25.11.2014 23:09:12
Интересно и по теме.
jwdonahue 22.01.2018 03:17:19
Но терпит неудачу со многими различными аргументами, например test.bat *.txt, test.bat cat^&dogилиTest.bat /?
jeb 12.02.2020 12:31:31

Давайте будем простыми.

Вот файл .cmd.

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

Вот 3 звонка из командной строки.

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>
22
31.12.2015 19:59:33

Я написал простой сценарий read_params, который можно вызывать как функцию (или внешнюю .bat) и помещать все переменные в текущую среду. Он не будет изменять исходные параметры, потому что функция редактируется callс копией исходных параметров.

Например, с помощью следующей команды:

myscript.bat some -random=43 extra -greeting="hello world" fluff

myscript.bat сможет использовать переменные после вызова функции:

call :read_params %*

echo %random%
echo %greeting%

Вот функция:

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

Ограничения

  • Невозможно загрузить аргументы без значения, такие как -force. Вы могли бы использовать, -force=trueно я не могу придумать способ разрешить пустые значения, не зная заранее список параметров, которые не будут иметь значения.

Изменения

  • 2/18/2016
    • Больше не требует отложенного расширения
    • Теперь работает с другими аргументами командной строки, ища -перед параметрами.
19
18.02.2016 22:29:05
Рассматривал использование этого метода, поскольку я хотел бы передать аргументы в командный файл таким образом. Однако я заметил, что после того, как переменные установлены, даже после выхода из пакетного файла параметры все еще устанавливаются в cmd, если доступ к ним и пакет завершен, они не восстанавливаются до своего предыдущего состояния. Должен ли этот метод справиться с этой ситуацией?
Jono_2007 14.09.2016 11:53:34
По теме и лучше, чем некоторые остальные ответы в этой теме.
jwdonahue 22.01.2018 03:14:57
Расширена поддержка флагов (без значений). Извините за отсутствие форматирования, но это не работает в комментариях: read_params, если не% 1 / == / (если не "% __ var%" == "" (если не "% __ var: ~ 0,1%" == "-" (endlocal goto read_params) endlocal & set% __ var: ~ 1% =% ~ 1) else (setlocal & set __var =% ~ 1) shift goto read_params) else (если не "% __ var%" == "" (endlocal & set% __ var: ~ 1% = 1))
Max 13.11.2019 19:26:44

Мой друг недавно спрашивал меня об этой теме, поэтому я подумал, что опубликую, как обрабатывать аргументы командной строки в пакетных файлах.

Как вы увидите, эта техника имеет некоторые накладные расходы, но она делает мои командные файлы очень простыми для понимания и быстрыми в реализации. А также поддерживая следующие структуры:

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

Тэк в нем , имеющие :init, :parseи :mainфункции.

Пример использования

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof
40
13.07.2017 03:32:46

Вдохновленный ответом в другом месте @Jon, я разработал более общий алгоритм для извлечения именованных параметров, необязательных значений и переключателей.

Допустим, мы хотим реализовать утилиту foobar. Требуется начальная команда. Он имеет необязательный параметр, --fooкоторый принимает необязательное значение (которое, конечно, не может быть другим параметром); если значение отсутствует, по умолчанию используется значение default. Он также имеет необязательный параметр, --barкоторый принимает требуемое значение. Наконец, он может принимать флаг --bazбез значения. Ох, и эти параметры могут прийти в любом порядке.

Другими словами, это выглядит так:

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

Вот решение:

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1
  • Используйте, SETLOCALчтобы переменные не попадали в вызывающую среду.
  • Не забудьте инициализировать переменные SET FOO=и т. Д. На случай, если кто-то определит их в вызывающей среде.
  • Используйте %~1для удаления кавычек.
  • Использование IF "%ARG%" == ""и не IF [%ARG%] == []потому , что [и ]не играют воли на все со значениями , заканчивающихся в пространстве.
  • Даже если вы SHIFTвнутри IFблока, текущие аргументы, такие как %~1, не обновляются, потому что они определяются при IFразборе. Вы можете использовать %~1и %~2внутри IFблока, но это будет сбивать с толку, потому что у вас есть SHIFT. Вы можете поставить SHIFTв конце блока для ясности, но это может потеряться и / или сбить людей с толку. Так что «захват» %~1и %~1вне блока кажется лучшим.
  • Вы не хотите использовать параметр вместо необязательного значения другого параметра, поэтому вы должны проверить IF NOT "%ARG:~0,2%" == "--".
  • Будьте осторожны только SHIFTпри использовании одного из параметров.
  • Повторяющийся код SET FOO=%DEFAULT_FOO%вызывает сожаление, но альтернативой будет добавление IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%внешнего IF NOT "%ARG%" == ""блока. Однако , поскольку это все еще внутри IF "%PARAM%" == "--foo"блока, то %FOO%стоимость была бы оценена и установить , прежде чем вы когда - либо вошел в блок, так что вы никогда не обнаружить , что и--foo параметр присутствует , а также о том , что %FOO%значение не было.
  • Обратите внимание, что ECHO Missing bar value. 1>&2отправляет сообщение об ошибке в stderr.
  • Хотите пустую строку в командном файле Windows? Вы должны использовать ECHO:или один из вариантов.
6
2.06.2018 02:48:08

Простое решение (хотя вопрос старый)

Test1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:\Temp\Test1.bat" pass123

вывод

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

Где YourLocalPath - это текущий путь к каталогу.

Для простоты сохраните команду param в переменной и используйте переменную для сравнения.

Его не просто написать, но и просто поддерживать, поэтому, если позже какой-то другой человек или вы прочтете свой сценарий после длительного периода времени, его будет легко понять и поддерживать.

Чтобы написать код в строке: см. Другие ответы.

2
3.07.2018 13:48:36

введите описание изображения здесь

Чтобы использовать цикл, получите все аргументы и в чистом пакетном режиме:

Obs: Для использования без:?*&<>


@echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && (
     call set "_arg_[!_cnt!]=!_arg_!" && for /l %%l in (!_cnt! 1 !_cnt!
     )do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

Ваш код готов сделать что-то с номером аргумента там, где это необходимо, например ...

 @echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"
 )

 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt
2
12.02.2020 13:12:28
Но это не удается, когда пароль содержит какой-либо символ?*&<>
jeb 12.02.2020 12:56:27
@jeb Еще раз спасибо, я добавил примечания : отвечать до нового редактирования для обработки этих символов ...
It Wasn't Me 12.02.2020 13:14:59

В пакетном файле

set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%

% 1 и% 2 возвращают первое и второе значения аргумента соответственно.

И в командной строке передайте аргумент

Directory> batchFileName admin P@55w0rd 

Выход будет

admin
P@55w0rd
8
18.10.2019 09:24:24